begin
  MAX_CONCURRENT = 6

  numTimeSteps = -1

  ;
  ; determine how many time steps from the file...
  ;
  f = addfile("sst8292.nc", "r")
  sst = f->SST 
  time = f->time

  wks = gsn_open_wks("png", "sst") 

  res                          = True

  res@gsnMaximize              = True
  res@cnFillOn                 = True
  res@cnFillPalette            = "rainbow"

  res@tmYROn                   = False

  res@lbOrientation            = "Vertical"
  res@pmLabelBarOrthogonalPosF = -0.02

  startPlotTime = systemfunc("date")

  do i=0, dimsizes(time)-1
    print("working on frame: " + i)
    yyyymm = cd_calendar(time(i), 0)
    res@tiMainString = sprinti("%02d", floattoint(yyyymm(0,1))) + "/" + sprinti("%4d", floattoint(yyyymm(0,0)))

    plot = gsn_csm_contour_map_ce(wks,sst(i,:,:),res)
  end do

  wallClockElapseTime(startPlotTime, "done generating plot frames", 0)

  startAnimateTime = systemfunc("date")
  ;
  ; use Imagemagick to create the animation from the *png frames...
  ; 
  system("convert -delay 100 -loop 0 sst*.png sst.gif")

  wallClockElapseTime(startAnimateTime, "done generating animation", 0)
    
end